[freeside-commits] freeside/FS/bin freeside-eftca-download, NONE, 1.1.2.2 freeside-eftca-upload, NONE, 1.1.2.2

Mark Wells mark at wavetail.420.am
Fri Jul 22 12:19:59 PDT 2011


Update of /home/cvs/cvsroot/freeside/FS/bin
In directory wavetail.420.am:/tmp/cvs-serv19394/FS/bin

Added Files:
      Tag: FREESIDE_2_3_BRANCH
	freeside-eftca-download freeside-eftca-upload 
Log Message:
EFT Canada batch format and scripts, #13628

--- NEW FILE: freeside-eftca-upload ---
#!/usr/bin/perl

use strict;
use Getopt::Std;
use Date::Format qw(time2str);
use File::Temp qw(tempdir);
use Net::SFTP::Foreign;
use FS::UID qw(adminsuidsetup dbh);
use FS::Record qw(qsearch qsearchs);
use FS::pay_batch;
use FS::Conf;

use vars qw( $opt_a $opt_v );
getopts('av');

#$Net::SFTP::Foreign::debug = -1;

sub HELP_MESSAGE { "
  Usage:
    freeside-eftca-upload [ -v ] user batchnum
    freeside-eftca-upload -a [ -v ] user\n
" }

my $user = shift or die &HELP_MESSAGE;
adminsuidsetup $user;

my @batches; 

if($opt_a) {
  @batches = qsearch('pay_batch', { 'status' => 'O', 'payby' => 'CHEK' })
    or die "No open batches found.\n";
}
else {
  my $batchnum = shift;
  die &HELP_MESSAGE if !$batchnum;
  @batches = qsearchs('pay_batch', { batchnum => $batchnum } );
  die "Can't find payment batch '$batchnum'\n" if !@batches;
}

my $conf = new FS::Conf;
my @batchconf = $conf->config('batchconfig-eft_canada');
my $username = $batchconf[0] or die "no EFT Canada batch username configured\n";
my $password = $batchconf[1] or die "no EFT Canada batch password configured\n";

my $tmpdir = tempdir( CLEANUP => 1 ); #DIR=>somewhere?

my @filenames;

foreach my $pay_batch (@batches) {
  my $batchnum = $pay_batch->batchnum;
  my $filename = time2str('%Y%m%d', time) . '-' . sprintf('%06d.csv',$batchnum);
  print STDERR "Exporting batch $batchnum to $filename...\n" if $opt_v;
  my $text = $pay_batch->export_batch('eft_canada');
  open OUT, ">$tmpdir/$filename";
  print OUT $text;
  close OUT;
  push @filenames, $filename;
}

my $host = 'ftp.eftcanada.com';
print STDERR "Connecting to $username\@$host...\n" if $opt_v;

my $sftp = Net::SFTP::Foreign->new( host => $host,
                                    user => $username,
                                    password => $password,
                                    timeout => 30,
                                    );
die "failed to connect to '$username\@$host'\n(".$sftp->error.")\n" 
    if $sftp->error;

foreach my $filename (@filenames) {
  $sftp->put("$tmpdir/$filename", "$filename")
    or die "failed to upload file (".$sftp->error.")\n";
}

$FS::UID::AutoCommit = 0;
foreach my $pay_batch (@batches) {
  # Auto-approve and close the batch.  Some false laziness with manual_approve.
  my $batchnum = $pay_batch->batchnum;
  my $error;
  foreach my $cpb ( qsearch('cust_pay_batch', { 'batchnum' => $batchnum } ) ) {
    $cpb->setfield('paid', $cpb->amount);
    $error = $cpb->approve($batchnum);
    last if $error;
  }
  $error ||= $pay_batch->set_status('R');
  die "error closing batch $batchnum: $error\n\n" if $error;
}
dbh->commit;

print STDERR "Finished!\n" if $opt_v;

=head1 NAME

freeside-eftca-upload - Transmit a payment batch to EFT Canada via SFTP.

=head1 SYNOPSIS

  freeside-paymentech-upload [ -a ] [ -v ] user batchnum

=head1 DESCRIPTION

Command line tool to upload a payment batch to the EFT Canada gateway.  The 
batch will be exported to a comma-delimited file and transmitted via SFTP.
Use L<freeside-eftca-download> to retrieve the response file.

-a: Send all open batches, instead of specifying a batchnum.

-v: Be verbose.

user: freeside username

batchnum: pay_batch primary key

=head1 SEE ALSO

L<FS::pay_batch>

=cut

1;


--- NEW FILE: freeside-eftca-download ---
#!/usr/bin/perl

use strict;
use Getopt::Std;
use Date::Format qw(time2str);
use File::Temp qw(tempdir);
use Net::SFTP::Foreign;
use Expect;
use FS::UID qw(adminsuidsetup datasrc);
use FS::Record qw(qsearch qsearchs);
use FS::pay_batch;
use FS::cust_pay_batch;
use FS::Conf;

use vars qw( $opt_v $opt_a );
getopts('va:');

#$Net::SFTP::Foreign::debug = -1;
sub HELP_MESSAGE { "
  Usage:
      freeside-eftca-download [ -v ] [ -a archivedir ] user\n
" }

my @fields = (
  'tid',          # transaction ID
  'paybatchnum',  # reference field
  'returncode',   # status code
  'returndate',
  'paid',         # dollars and cents, with decimal
  'type',
  'first',
  'last',
  'account',
  'bank',
  'transit',
);

my $user = shift or die &HELP_MESSAGE;
adminsuidsetup $user;

if ( $opt_a ) {
  die "no such directory: $opt_a\n"
    unless -d $opt_a;
  die "archive directory $opt_a is not writable by the freeside user\n"
    unless -w $opt_a;
}

#my $tmpdir = File::Temp->newdir();
my $tmpdir = tempdir( CLEANUP => 1 ); #DIR=>somewhere?

my $conf = new FS::Conf;
my @batchconf = $conf->config('batchconfig-eft_canada');
# BIN, terminalID, merchantID, username, password
my $username = $batchconf[0] or die "no EFT Canada batch username configured\n";
my $password = $batchconf[1] or die "no EFT Canada batch password configured\n";

my $host = 'ftp.eftcanada.com';
print STDERR "Connecting to $username\@$host...\n" if $opt_v;

my $sftp = Net::SFTP::Foreign->new( host => $host,
                                    user => $username,
                                    password => $password,
                                    timeout => 30,
                                    );
die "failed to connect to '$username\@$host'\n(".$sftp->error.")\n" if $sftp->error;

$sftp->setcwd('/Returns');

my $files = $sftp->ls('.', wanted => qr/^ReturnFile/, names_only => 1);
die "no response files found\n" if !@$files;

FILE: foreach my $filename (@$files) {
  print STDERR "Retrieving $filename\n" if $opt_v;
  $sftp->get("$filename", "$tmpdir/$filename");
  if($sftp->error) {
    warn "failed to download $filename\n";
    next FILE;
  }

  #move to server archive dir
  $sftp->rename("$filename", "Archive/$filename");
  if($sftp->error) {
    warn "failed to archive $filename on server\n";
  } # process it anyway though

  #copy to local archive dir
  if ( $opt_a ) {
    print STDERR "Copying $tmpdir/$filename to archive dir $opt_a\n"
      if $opt_v;
    system 'cp', "$tmpdir/$filename", $opt_a;
    warn "failed to copy $tmpdir/$filename to $opt_a: $@" if $@;
  }

  open my $fh, "<$tmpdir/$filename";
  # Some duplication with FS::pay_batch::import_results, but we're really 
  # doing something different here.
  my $csv = new Text::CSV_XS ( { quote_char => undef, sep_char => '|' } );
  my %hash;
  while (my $line = <$fh>) {
    next if $line =~ /^\s*$/;
    $csv->parse($line) or do {
      warn "can't parse $filename: ".$csv->error_input."\n";
      next FILE; #parsing errors = reading the wrong kind of file
    };
    @hash{@fields} = $csv->fields();
    print STDERR "voiding paybatchnum#$hash{paybatchnum}\n" if $opt_v;
    my $cpb = qsearchs('cust_pay_batch', 
                        { paybatchnum => $hash{'paybatchnum'} });
    if ( !$cpb ) {
      warn "can't find paybatchnum #$hash{paybatchnum} ($hash{first} $hash{last}, $hash{paid})\n";
      next;
    }
    my $error = $cpb->decline("Returned payment ($hash{returncode})");
    if ( $error ) {
      warn "can't void paybatchnum #$hash{paybatchnum}: $error\n";
    }
  }
  close $fh;
}

print STDERR "Finished!\n" if $opt_v;

=head1 NAME

freeside-eftca-download - Retrieve payment batch responses from EFT Canada.

=head1 SYNOPSIS

  freeside-eftca-download [ -v ] [ -a archivedir ] user

=head1 DESCRIPTION

Command line tool to download returned payment reports from the EFT Canada 
gateway and void the returned payments.  Uses the login and password from 
'batchconfig-eft_canada'.

-v: Be verbose.

-a directory: Archive response files in the provided directory.

user: freeside username

=head1 BUGS

You need to manually SFTP to ftp.eftcanada.com from the freeside account 
and accept their key before running this script.

=head1 SEE ALSO

L<FS::pay_batch>

=cut

1;




More information about the freeside-commits mailing list