freeside/FS/FS/part_export artera_turbo.pm,NONE,1.1

[ivan]

Update of /home/cvs/cvsroot/freeside/FS/FS/part_export
In directory pouncequick:/tmp/cvs-serv25467/FS/FS/part_export

Added Files:
	artera_turbo.pm 
Log Message:
add artera turbo export

--- NEW FILE: artera_turbo.pm ---
package FS::part_export::artera_turbo;

use vars qw(@ISA %info);
use Tie::IxHash;
use FS::Record qw(qsearch);
use FS::part_export;
use FS::cust_svc;
use FS::svc_external;

@ISA = qw(FS::part_export);

tie my %options, 'Tie::IxHash',
  'rid'        => { 'label' => 'Reseller ID (RID)' },
  'username'   => { 'label' => 'Reseller username', },
  'password'   => { 'label' => 'Reseller password', },
  'pid'        => { 'label' => 'Artera Product ID', },
  'priceid'    => { 'label' => 'Artera Price ID', },
  'agent_aid'  => { 'label' => 'Export agentnum values to Artera AID',
                    'type'  => 'checkbox',
                  },
  'production' => { 'label' => 'Production mode (leave unchecked for staging)',
                    'type'  => 'checkbox',
                  },
;

%info = (
  'svc'      => 'svc_external',
  #'svc'      => [qw( svc_acct svc_forward )],
  'desc'     =>
    'Real-time export to Artera Turbo Reseller API',
  'options'  => \%options,
  #'nodomain' => 'Y',
  'notes'    => <<'END'
Real-time export to <a href="http://www.arteraturbo.com/">Artera Turbo</a>
Reseller API.  Requires installation of
<a href="http://search.cpan.org/dist/Net-Artera">Net::Artera</a>
from CPAN.
END
);

sub rebless { shift; }

sub _new_Artera {
  my $self = shift;

  my $artera = new Net::Artera (
    map { $_ => $self->option($_) }
        qw( rid username password production )
  );
}


sub _export_insert {
  my($self, $svc_external) = (shift, shift);

  # want the ASN (serial) and AKC (key code) right away

  eval "use Net::Artera;";
  return $@ if $@;

  my $artera = $self->_new_Artera;

  my $cust_pkg = $svc_external->cust_svc->cust_pkg;
  my $part_pkg = $cust_pkg->part_pkg;
  my @svc_acct = grep { $_->table eq 'svc_acct' }
                 map { $_->svc_x }
                 sort { my $svcpart = $part_pkg->svcpart('svc_acct');
                        ($b->svcpart==$svcpart) cmp ($a->svcpart==$svcpart); }
                 qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
  my $email = scalar(@svc_acct) ? $svc_acct[0]->email : '';
  
  my $cust_main = $cust_pkg->cust_main;

  my $result = $artera->newOrder(
    'pid'     => $self->option('pid'),
    'priceid' => $self->option('priceid'),
    'email'   => $email,
    'cname'   => $cust_main->name,
    'ref'     => $svc_external->svcnum,
    'aid'     => ( $self->option('agent_aid') ? $cust_main->agentnum : '' ),
    'add1'    => $cust_main->address1,
    'add2'    => $cust_main->address2,
    'add3'    => $cust_main->city,
    'add4'    => $cust_main->state,
    'zip'     => $cust_main->zip,
    'cid'     => $cust_main->country,
    'phone'   => $cust_main->daytime || $cust_main->night,
    'fax'     => $cust_main->fax,
  );

  if ( $result->{'id'} == 1 ) {
    my $new = new FS::svc_external { $svc_external->hash };
    $new->id($result->{'ASN'});
    $new->title($result->{'AKC'});
    $new->replace($svc_external);
  } else {
    $result->{'message'} || 'No response from Artera';
  }
}

sub _export_replace {
  my( $self, $new, $old ) = (shift, shift, shift);
  #except the first time, hehe..
  #return "can't change serial number with Artera"
  #  if $old->id != $new->id;
  #return "can't change key code with Artera"
  #  if $old->title ne $new->title;
  '';
}

sub _export_delete {
  my( $self, $svc_external ) = (shift, shift);
  $self->StatusChange(17, $svc_external);
}

sub _export_suspend {
  my( $self, $svc_external ) = (shift, shift);
  $self->StatusChange(16, $svc_external);
}

sub _export_unsuspend {
  my( $self, $svc_external ) = (shift, shift);
  $self->StatusChange(15, $svc_external);
}

sub StatusChange {
  my( $self, $status, $svc_external ) = @_;

  my $artera = $self->_new_Artera;

  my $result = $artera->StatusChange(
    'asn'      => sprintf('%010d', $svc_external->id),
    'akc'      => $svc_external->title,
    'statusid' => $status,
  );

  $result->{'id'} == 1
    ? ''
    : $result->{'message'};
}

1;